SetFactory("OpenCASCADE");

t0 = Cpu ;
Printf("InitialTime = ", t0);

Merge "benchmarking.brep";

t1 = Cpu ;
Printf("LoadedTime = ", t0);

X = .4;        // size of domain in x-direction
Y = .4;        // size of domain in y-direction
Z = 1.6;        // size of domain in z-direction

LC = 0.009;    // mesh critical length

all_surfaces[]=Surface "*";
dr = 1e-6;

back[] = Surface In BoundingBox {-dr,-dr,-dr,2*dr,Y+2*dr,Z+2*dr};
left[] = Surface In BoundingBox {-dr,-dr,-dr,X+2*dr,2*dr,Z+2*dr};
bottom[] = Surface In BoundingBox {-dr,-dr,-dr,X+2*dr,Y+2*dr,2*dr};

front[] = Surface In BoundingBox {X-dr,-dr,-dr,X+2*dr,Y+2*dr,Z+2*dr};
right[] = Surface In BoundingBox {-dr,Y-dr,-dr,X+2*dr,Y+2*dr,Z+2*dr};
top[] = Surface In BoundingBox {-dr,-dr,Z-dr,X+2*dr,Y+2*dr,Z+2*dr};

interior[]=all_surfaces[];
interior[]-=back[];
interior[]-=left[];
interior[]-=bottom[];
interior[]-=front[];
interior[]-=right[];
interior[]-=top[];

Physical Volume("Medium")={1};

Physical Surface("Back") = back[];
Physical Surface("Left") = left[];
Physical Surface("Bottom") = bottom[];
Physical Surface("Front") = front[];
Physical Surface("Right") = right[];
Physical Surface("Top") = top[];

Physical Surface("Interior") = interior[];


//Printf("allSurfaces = ",all_surfaces[]);
Printf("BackIndex = ",back[]);
Printf("LeftIndex = ",left[]);
Printf("BottomIndex = ",bottom[]);
Printf("FrontIndex = ",front[]);
Printf("RightIndex = ",right[]);
Printf("TopIndex = ",top[]);


t2 = Cpu ;
Printf("NamedSurfaces = ", t2);


// Define the meshing parameters
Field[1] = Box;
Field[1].VIn = LC;
Field[1].VOut = LC;
Field[1].XMin = 0;
Field[1].XMax = X;
Field[1].YMin = 0;
Field[1].YMax = Y;
Field[1].ZMin = 0;
Field[1].ZMax = Z;

Background Field = 1;

Mesh 2;

t3 = Cpu ;
Printf("Meshed 2D= ", t3);

Mesh 3;

t4 = Cpu ;
Printf("Meshed 3D = ", t4);

Printf("MeshingTime 2D = ", t3-t2);
Printf("MeshingTime 3D = ", t4-t3);
Printf("MeshingTime, total = ", t4-t2);