// Gmsh project created on Tue Mar 12 09:19:29 2013

mm = 1e-3;

// Characterisitc length
lc_Top    = 0.1*mm;
lc_Mid    = 0.2*mm;
lc_Bottom = 0.4*mm;

Point(1) = {0*mm, 0*mm, 0*mm, lc_Mid};
Point(2) = {5*mm, 0*mm, 0*mm, lc_Mid};
Point(3) = {5*mm, 3*mm, 0*mm, lc_Mid};
Point(4) = {0*mm, 3*mm, 0*mm, lc_Top};
Point(5) = {0*mm, 2*mm, 0*mm, lc_Top};
Point(6) = {3*mm, 2*mm, 0*mm, lc_Top};
Point(7) = {3*mm, 3*mm, 0*mm, lc_Top};

Point(8) = {1.50*mm, 1.00*mm, 0*mm, lc_Mid};
Point(9) = {1.50*mm, 0.50*mm, 0*mm, lc_Mid};
Point(10)= {2.00*mm, 1.00*mm, 0*mm, lc_Mid};
Point(11)= {1.50*mm, 1.50*mm, 0*mm, lc_Mid};
Point(12)= {1.00*mm, 1.00*mm, 0*mm, lc_Mid};

Circle(1) = {9, 8, 10};
Circle(2) = {10, 8, 11};
Circle(3) = {11, 8, 12};
Circle(4) = {12, 8, 9};
Line(5) = {5, 6};
Line(6) = {6, 7};
Line(7) = {7, 4};
Line(8) = {4, 5};
Line(9) = {5, 1};
Line(10) = {1, 2};
Line(11) = {2, 3};
Line(12) = {3, 7};
Line Loop(13) = {9, 10, 11, 12, -6, -5};
Line Loop(14) = {3, 4, 1, 2};
Plane Surface(15) = {13, 14};
Line Loop(16) = {8, 5, 6, 7};
Plane Surface(17) = {16};
Extrude {0, 0, -3.00*mm} {
  Surface{15, 17};
}
Extrude {0, 0, 1.00*mm} {
  Surface{17}; Layers{ 15 }; Recombine; 
}

// Set characteristic length
Characteristic Length {50, 13, 14, 18, 22, 26, 30, 37, 39, 44, 49} = lc_Bottom;

// Physical numbers
SurBottom = 1;
SurTop    = 2;
VolSteel  = 3;
VolCopper = 4;

Physical Surface(SurBottom) = {69, 91};		// Bottom
Color LightSteelBlue1 { Surface{69, 91}; }
Physical Surface(SurTop) = {113};			// Top
Color OrangeRed1{ Surface{113}; }

Physical Volume(VolSteel) = {1, 2};		// Steel (lower body)
Color LightSteelBlue1 { Volume{1, 2}; }	
Physical Volume(VolCopper) = {3};		// Copper (upper body)
Color OrangeRed1 { Volume{3}; }	

// Mesh algorithm
Mesh.Algorithm = 2;   // 1=MeshAdapt, 2=Automatic, 5=Delaunay, 6=Frontal, 7=bamg, 8=delquad
Mesh.Algorithm3D = 4; // 1=Delaunay, 4=Frontal, 5=Frontal Delaunay, 6=Frontal Hex, 7=MMG3D, 9=R-tree